1 files changed, 59 insertions, 0 deletions
diff --git a/dev-libs/libevent/libevent-scm.ebuild b/dev-libs/libevent/libevent-scm.ebuild
new file mode 100644
index 0000000..bb6d7dc
--- /dev/null
+++ b/dev-libs/libevent/libevent-scm.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils git-r3 multilib-minimal
+
+DESCRIPTION="Library to execute a function when a specific event occurs on a file descriptor"
+HOMEPAGE="http://libevent.org/"
+EGIT_REPO_URI="https://github.com/libevent/libevent"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug libressl +ssl static-libs test +threads"
+RESTRICT="test"
+
+DEPEND="
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+		libressl? ( =dev-libs/libressl-scm[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="
+	${DEPEND}
+	!<=dev-libs/9libs-1.0
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/event2/event-config.h
+)
+DOCS=(
+	ChangeLog{,-1.4,-2.0}
+)
+
+src_prepare() {
+	default
+	use libressl && eapply "${FILESDIR}/libressl.patch"
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# fix out-of-source builds
+	mkdir -p test || die
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-samples \
+		$(use_enable debug debug-mode) \
+		$(use_enable debug malloc-replacement) \
+		$(use_enable ssl openssl) \
+		$(use_enable static-libs static) \
+		$(use_enable test libevent-regress) \
+		$(use_enable threads thread-support)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}