4 files changed, 613 insertions, 0 deletions
diff --git a/dev-libs/Ice/Ice-3.6.3-r2.ebuild b/dev-libs/Ice/Ice-3.6.3-r2.ebuild
new file mode 100644
index 0000000..f4a98d7
--- /dev/null
+++ b/dev-libs/Ice/Ice-3.6.3-r2.ebuild
@@ -0,0 +1,349 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} pypy )
+
+RUBY_OPTIONAL="yes"
+USE_RUBY="ruby22"
+
+PHP_EXT_NAME="IcePHP"
+PHP_EXT_INI="yes"
+PHP_EXT_ZENDEXT="no"
+
+PHP_EXT_OPTIONAL_USE=php
+
+USE_PHP="php7-0 php5-6 php5-5 php5-4"
+
+# This variable does not belong to any eclass. It is solely used in this ebuild
+# db:6.2 breaks the build process
+BERKDB_SLOTS=( 6.1 5.3 5.1 4.8 )
+
+inherit db-use eutils mono-env php-ext-source-r2 python-r1 ruby-ng toolchain-funcs versionator
+
+DESCRIPTION="ICE middleware C++ library and generator tools"
+HOMEPAGE="https://zeroc.com/products/ice"
+SRC_URI="https://github.com/zeroc-ice/ice/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	doc? ( http://download.zeroc.com/Ice/$(get_version_component_range 1-2)/${P}.pdf )"
+LICENSE="GPL-2"
+SLOT="0/36"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc examples libressl +ncurses mono php python ruby test debug"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND=">=dev-libs/expat-2.0.1
+	>=app-arch/bzip2-1.0.5
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	|| (
+		$(for slot in ${BERKDB_SLOTS[@]} ; do printf '%s\n' "sys-libs/db:${slot}[cxx]" ; done)
+	)
+	dev-cpp/libmcpp
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( $(ruby_implementation_depend ruby22) )
+	mono? ( dev-lang/mono )
+	php? ( dev-lang/php )
+	!dev-python/IcePy
+	!dev-ruby/IceRuby"
+DEPEND="${RDEPEND}
+	ncurses? ( sys-libs/ncurses:0= sys-libs/readline:0= )
+	test? (
+		${PYTHON_DEPS}
+		dev-python/passlib[${PYTHON_USEDEP}]
+	)"
+
+# Maintainer notes:
+# TODO: java bindings, multiple ruby versions (supports 2.{1,2,3})
+
+S="${WORKDIR}/${P/I/i}"
+PHP_EXT_S="${S}/php"
+
+PATCHES=(
+	"${FILESDIR}/${P}-no-arch-opts.patch"
+	"${FILESDIR}/${P}-csharp.patch"
+	"${FILESDIR}/${P}-libressl.patch"
+)
+
+pkg_setup() {
+	# prevent ruby-ng.eclass from messing with pkg_setup
+	return
+}
+
+src_unpack() {
+	# prevent ruby-ng.eclass from messing with src_unpack
+	default
+}
+
+src_prepare() {
+	epatch -p1 "${PATCHES[@]}"
+
+	sed -i \
+		-e 's|\(install_configdir[[:space:]]*\):=|\1?=|' \
+		-e 's|-L\$\(libdir\)||' \
+		cpp/config/Make.rules || die "sed failed"
+
+	sed -i \
+		-e 's|\(install_phpdir[[:space:]]*\):=|\1?=|' \
+		-e 's|\(install_libdir[[:space:]]*\):=|\1?=|' \
+		php/config/Make.rules.php || die "sed failed"
+
+	sed -i \
+		-e 's|\(install_pythondir[[:space:]]*\)=|\1?=|' \
+		-e 's|\(install_rubydir[[:space:]]*\)=|\1?=|' \
+		-e 's|\(install_libdir[[:space:]]*\):=|\1?=|' \
+		{python,ruby}/config/Make.rules || die "sed failed"
+
+	sed -i \
+		-e 's|-O2 ||g' \
+		-e 's|-Werror ||g' \
+		cpp/config/Make.rules.Linux || die "sed failed"
+
+	sed -i \
+		-e 's|install-common||' \
+		{cpp,csharp,php,python,ruby}/Makefile || die "sed failed"
+
+	sed -i \
+		-e 's|-f -root|-f -gacdir $(GAC_DIR) -root|' \
+		-e 's|\(install_libdir[[:space:]]*\):=|\1?=|' \
+		-e 's|\(install_pkgconfigdir[[:space:]]*\):=|\1?=|' \
+		csharp/config/Make.rules.cs || die "sed failed"
+
+	# skip mono tests, bug #498484
+	sed -i \
+		-e '/SUBDIRS/s|\ test||' \
+		csharp/Makefile || die "sed failed"
+
+	# IceUtil/stacktrace fails with USE=debug
+	# skip udp test due to multicast
+	# skip IceSSL tests due to requirement of internet connection
+	# IceStorm/stress fails without USE=debug
+	sed -i \
+		-e 's|allTests.py|allTests.py --rfilter=IceUtil\/stacktrace --rfilter=udp --rfilter=IceSSL --rfilter=IceStorm\/stress|' \
+		cpp/Makefile || die "sed failed"
+
+	# mainly broken .ice files
+	sed -i \
+		-e 's|allTests.py|allTests.py --rfilter=operations --rfilter=slicing\/objects|' \
+		python/Makefile || die "sed failed"
+
+	# fails even on unicode locale
+	sed -i \
+		-e 's|allTests.py|allTests.py --rfilter=Slice\/unicodePaths|' \
+		ruby/Makefile || die "sed failed"
+}
+
+src_configure() {
+	suitable_db_version() {
+		local ver
+		for ver in "${BERKDB_SLOTS[@]}"; do
+			if [[ -n $(db_findver sys-libs/db:${ver}) ]]; then
+				echo "${ver}"
+				return 0
+			fi
+		done
+		die "No suitable BerkDB versions found, aborting"
+	}
+
+	MAKE_RULES=(
+		"prefix=\"${ED%/}/usr\""
+		"install_docdir=\"${ED%/}/usr/share/doc/${PF}\""
+		"install_configdir=\"${ED%/}/usr/share/${P}/config\""
+		"install_mandir=\"${ED%/}/usr/share/man\""
+		"embedded_runpath_prefix=\"${EPREFIX}/usr\""
+		"LP64=yes"
+		"new_dtags=yes"
+		"NOTEST=$(usex !test)"
+		"USE_READLINE=$(usex ncurses)"
+		"OPTIMIZE=$(usex !debug)"
+	)
+
+	local BERKDB_VERSION="$(suitable_db_version)"
+	MAKE_RULES+=("DB_FLAGS=-I$(db_includedir ${BERKDB_VERSION})")
+	sed -i \
+		-e "s|g++|$(tc-getCXX)|" \
+		-e "s|\(CFLAGS[[:space:]]*=\)|\1 ${CFLAGS}|" \
+		-e "s|\(CXXFLAGS[[:space:]]*=\)|\1 ${CXXFLAGS}|" \
+		-e "s|\(LDFLAGS[[:space:]]*=\)|\1 ${LDFLAGS}|" \
+		-e "s|\(DB_LIBS[[:space:]]*=\) \-ldb_cxx|\1 -ldb_cxx-$(db_findver sys-libs/db:${BERKDB_VERSION})|" \
+		cpp/config/Make.rules{,.Linux} python/config/Make.rules || die "sed failed"
+
+	if use python; then
+		local S="${S}/python"
+		python_copy_sources
+	fi
+
+	if use ruby; then
+		SITERUBY="$(ruby22 -r rbconfig -e 'print RbConfig::CONFIG["sitelibdir"]')"
+		MAKE_RULES_RUBY=(
+			"install_rubydir=\"${ED%/}/${SITERUBY}\""
+			"install_libdir=\"${ED%/}/${SITERUBY}\""
+		)
+
+		# make it use ruby22 only
+		sed -i \
+			-e 's|RUBY = ruby|\022|' \
+			ruby/config/Make.rules || die "sed failed"
+		sed -i \
+			-e 's|env ruby|\022|' \
+			ruby/config/s2rb.rb || die "sed failed"
+		sed -i \
+			-e 's|env ruby|\022|' \
+			ruby/scripts/slice2rb || die "sed failed"
+		sed -i \
+			-e 's|output.write("ruby|\022|' \
+			scripts/TestUtil.py || die "sed failed"
+	fi
+
+	MAKE_RULES_MONO=(
+		"GACINSTALL=yes"
+		"GAC_ROOT=\"${ED%/}/usr/$(get_libdir)\""
+		"GAC_DIR=\"${EPREFIX}/usr/$(get_libdir)\""
+		"install_libdir=\"${ED%/}/usr/$(get_libdir)\""
+		"install_pkgconfigdir=\"${ED%/}/usr/$(get_libdir)/pkgconfig\""
+	)
+
+	if has_version ">dev-lang/mono-4"; then
+		MAKE_RULES_MONO+=("MCS=mcs")
+	fi
+
+	use test && python_setup
+}
+
+src_compile() {
+	# Do not remove this export or build will break!
+	tc-export CXX
+
+	emake -C cpp "${MAKE_RULES[@]}"
+
+	if use php; then
+		local i
+		for i in $(php_get_slots); do
+			mkdir -p "${WORKDIR}/${i}" || die
+			cp -r "${PHP_EXT_S}" "${WORKDIR}/${i}/" || die "Failed to copy source ${PHP_EXT_S} to PHP target directory"
+
+			pushd "${WORKDIR}/${i}" >/dev/null || die
+			ln -s "${S}/cpp" || die
+			ln -s "${S}/config" || die
+			ln -s "${S}/slice" || die
+			ln -s "${S}/Makefile" || die
+
+			emake -C php "${MAKE_RULES[@]}" USE_NAMESPACES=yes "PHP_CONFIG=\"${EPREFIX}/usr/$(get_libdir)/${i}/bin/php-config\""
+			popd >/dev/null || die
+		done
+	fi
+
+	if use python; then
+		building() {
+			emake -C "${BUILD_DIR}" "${MAKE_RULES[@]}" PYTHON="${EPYTHON}"
+		}
+		local S="${S}/python"
+		python_foreach_impl building
+	fi
+
+	if use ruby; then
+		emake -C ruby "${MAKE_RULES[@]}" "${MAKE_RULES_RUBY[@]}"
+	fi
+
+	if use mono; then
+		emake -C csharp "${MAKE_RULES[@]}" "${MAKE_RULES_MONO[@]}"
+	fi
+}
+
+src_test() {
+	local -x LD_LIBRARY_PATH="${S}/cpp/$(get_libdir)${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
+	emake -C cpp "${MAKE_RULES[@]}" test
+
+	# php tests require the extension loaded and are therefore skipped
+
+	if use python; then
+		testing() {
+			emake -C "${BUILD_DIR}" \
+				"${MAKE_RULES[@]}" \
+				PYTHON="${EPYTHON}" \
+				install_pythondir="\"${D%/}/$(python_get_sitedir)\"" \
+				install_libdir="\"${D%/}/$(python_get_sitedir)\"" test
+		}
+		local S="${S}/python"
+		python_foreach_impl testing
+	fi
+
+	if use ruby; then
+		emake -C ruby "${MAKE_RULES[@]}" "${MAKE_RULES_RUBY[@]}" test
+	fi
+
+	if use mono; then
+		# skip mono tests, bug #498484
+		ewarn "Tests for C# are currently disabled."
+		#emake -C csharp "${MAKE_RULES[@]}" "${MAKE_RULES_MONO[@]}" test
+	fi
+}
+
+src_install() {
+	local DOCS=( CHANGELOG*.md README.md )
+	use doc && DOCS+=( "${DISTDIR}/${P}.pdf" )
+	einstalldocs
+
+	insinto /usr/share/${P}
+	doins -r slice
+
+	emake -C cpp "${MAKE_RULES[@]}" install
+
+	if use examples; then
+		docinto examples-cpp
+		dodoc cpp/config/*.cfg
+		docompress -x /usr/share/doc/${PF}/examples-cpp
+	fi
+
+	if use php; then
+		insinto "/usr/share/php/${PN}"
+
+		local i
+		while IFS="" read -d $'\0' -r i; do
+			doins "${i}"
+		done < <(find "${S}/php/lib/" -name '*.php' -print0)
+
+		pushd "${ED%/}/usr/share/${P}/slice" >/dev/null || die
+
+		local -x LD_LIBRARY_PATH="${ED%/}/usr/$(get_libdir):${LD_LIBRARY_PATH}"
+		for i in *; do
+			mkdir -p "${ED%/}/usr/share/php/${i}" || die
+			"${ED%/}"/usr/bin/slice2php \
+				-I"${ED%/}/usr/share/${P}/slice/" --all \
+				--output-dir "${ED%/}/usr/share/php/${i}" \
+				--ice "${ED%/}/usr/share/${P}/slice/${i}"/*
+		done
+
+		for i in $(php_get_slots); do
+			php_init_slot_env "${i}"
+			insinto "${EXT_DIR}"
+			newins "php/lib/${PHP_EXT_NAME}.so" "${PHP_EXT_NAME}.so"
+		done
+		php-ext-source-r2_createinifiles
+
+		popd >/dev/null || die
+	fi
+
+	if use python; then
+		installation() {
+			mkdir -p "${D%/}/$(python_get_sitedir)" || die
+
+			emake -C "${BUILD_DIR}" \
+				"${MAKE_RULES[@]}" \
+				install_pythondir="\"${D%/}/$(python_get_sitedir)\"" \
+				install_libdir="\"${D%/}/$(python_get_sitedir)\"" \
+				install
+		}
+		local S="${S}/python"
+		python_foreach_impl installation
+	fi
+
+	if use ruby; then
+		dodir "${SITERUBY}"
+		emake -C ruby "${MAKE_RULES[@]}" "${MAKE_RULES_RUBY[@]}" install
+	fi
+
+	if use mono; then
+		emake -C csharp "${MAKE_RULES[@]}" "${MAKE_RULES_MONO[@]}" install
+	fi
+}
diff --git a/dev-libs/Ice/files/Ice-3.6.3-csharp.patch b/dev-libs/Ice/files/Ice-3.6.3-csharp.patch
new file mode 100644
index 0000000..e9dce11
--- /dev/null
+++ b/dev-libs/Ice/files/Ice-3.6.3-csharp.patch
@@ -0,0 +1,50 @@
+--- ice-3.6.3/csharp/src/Makefile~	2015-06-23 17:30:20.000000000 +0200
++++ ice-3.6.3/csharp/src/Makefile	2015-06-27 20:07:04.217188211 +0200
+@@ -11,7 +11,7 @@
+ 
+ include $(top_srcdir)/config/Make.rules.cs
+ 
+-SUBDIRS		= Ice IceStorm Glacier2 IcePatch2 IceGrid IceBox IceDiscovery IceLocatorDiscovery
++SUBDIRS		= Ice IceStorm Glacier2 IcePatch2 IceGrid IceBox IceSSL IceDiscovery IceLocatorDiscovery
+ 
+ $(EVERYTHING)::
+ 	@for subdir in $(SUBDIRS); \
+--- /dev/null	2015-06-27 16:44:15.733558105 +0200
++++ ice-3.6.3/csharp/lib/pkgconfig/IceSSL.pc	2015-06-27 20:19:30.731894653 +0200
+@@ -0,0 +1,10 @@
++version = 3.6.3
++mono_root = /usr
++
++name = IceSSL
++
++Name: ${name}
++Description: IceSSL run-time support
++Version: ${version}
++Libs: -r:${mono_root}/lib/mono/${name}/${name}.dll
++Requires: Ice = ${version}
+--- /dev/null	2015-06-27 16:44:15.733558105 +0200
++++ ice-3.6.3/csharp/lib/pkgconfig/IceDiscovery.pc	2015-06-27 20:20:44.312515987 +0200
+@@ -0,0 +1,10 @@
++version = 3.6.3
++mono_root = /usr
++
++name = IceDiscovery
++
++Name: ${name}
++Description: IceDiscovery run-time support
++Version: ${version}
++Libs: -r:${mono_root}/lib/mono/${name}/${name}.dll
++Requires: Ice = ${version}
+--- /dev/null	2015-06-27 16:44:15.733558105 +0200
++++ ice-3.6.3/csharp/lib/pkgconfig/IceLocatorDiscovery.pc	2015-06-27 20:21:22.206185123 +0200
+@@ -0,0 +1,10 @@
++version = 3.6.3
++mono_root = /usr
++
++name = IceLocatorDiscovery
++
++Name: ${name}
++Description: IceLocatorDiscovery run-time support
++Version: ${version}
++Libs: -r:${mono_root}/lib/mono/${name}/${name}.dll
++Requires: Ice = ${version}
diff --git a/dev-libs/Ice/files/Ice-3.6.3-libressl.patch b/dev-libs/Ice/files/Ice-3.6.3-libressl.patch
new file mode 100644
index 0000000..e7d42e3
--- /dev/null
+++ b/dev-libs/Ice/files/Ice-3.6.3-libressl.patch
@@ -0,0 +1,164 @@
+From cbbac2c31a04e956261489ce75c962be7e2454ae Mon Sep 17 00:00:00 2001
+From: Joe George <joe@zeroc.com>
+Date: Mon, 12 Dec 2016 11:51:41 -0500
+Subject: [PATCH] ICE-7445 - Add libressl build support
+
+---
+ cpp/src/IceSSL/OpenSSLEngine.cpp       | 20 ++++++++++----------
+ cpp/src/IceSSL/OpenSSLTransceiverI.cpp |  6 +++---
+ cpp/src/IceSSL/Util.cpp                |  8 ++++----
+ 3 files changed, 17 insertions(+), 17 deletions(-)
+
+diff --git a/cpp/src/IceSSL/OpenSSLEngine.cpp b/cpp/src/IceSSL/OpenSSLEngine.cpp
+index 8c45950..7360d06 100644
+--- a/cpp/src/IceSSL/OpenSSLEngine.cpp
++++ b/cpp/src/IceSSL/OpenSSLEngine.cpp
+@@ -43,7 +43,7 @@ IceUtil::Mutex* staticMutex = 0;
+ int instanceCount = 0;
+ bool initOpenSSL = false;
+ 
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L
++#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
+ IceUtil::Mutex* locks = 0;
+ #endif
+ 
+@@ -59,10 +59,10 @@ class Init
+     ~Init()
+     {
+         //
+-        // OpenSSL 1.1.0 introduces a new thread API and removes 
++        // OpenSSL 1.1.0 introduces a new thread API and removes
+         // the need to use a custom thread callback.
+         //
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L
++#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
+         CRYPTO_set_locking_callback(0);
+         CRYPTO_set_id_callback(0);
+ 
+@@ -84,10 +84,10 @@ extern "C"
+ {
+ 
+ //
+-// OpenSSL 1.1.0 introduces a new thread API and removes 
++// OpenSSL 1.1.0 introduces a new thread API and removes
+ // the need to use a custom thread callback.
+ //
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L
++#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
+ //
+ // OpenSSL mutex callback.
+ //
+@@ -158,7 +158,7 @@ IceSSL_opensslPasswordCallback(char* buf, int size, int flag, void* userData)
+ DH*
+ IceSSL_opensslDHCallback(SSL* ssl, int /*isExport*/, int keyLength)
+ {
+-#  if OPENSSL_VERSION_NUMBER >= 0x10100000L
++#  if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
+     SSL_CTX* ctx = SSL_get_SSL_CTX(ssl);
+ #  else
+     SSL_CTX* ctx = ssl->ctx;
+@@ -219,7 +219,7 @@ OpenSSLEngine::OpenSSLEngine(const CommunicatorPtr& communicator) :
+             //
+             // OpenSSL 1.1.0 remove the need for library initialization and cleanup.
+             //
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L
++#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
+             //
+             // Create the mutexes and set the callbacks.
+             //
+@@ -326,7 +326,7 @@ OpenSSLEngine::~OpenSSLEngine()
+ //
+ // OpenSSL 1.1.0 remove the need for library initialization and cleanup.
+ //
+-#if OPENSSL_VERSION_NUMBER < 0x10100000L
++#if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
+     //
+     // Clean up OpenSSL resources.
+     //
+@@ -399,7 +399,7 @@ OpenSSLEngine::initialize()
+                                                     "IceSSL: unable to create SSL context:\n" + sslErrors());
+             }
+ 
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L
++#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
+             int securityLevel = properties->getPropertyAsIntWithDefault(propPrefix + "SecurityLevel", -1);
+             if(securityLevel != -1)
+             {
+@@ -954,7 +954,7 @@ OpenSSLEngine::parseProtocols(const StringSeq& protocols) const
+ SSL_METHOD*
+ OpenSSLEngine::getMethod(int /*protocols*/)
+ {
+-#if OPENSSL_VERSION_NUMBER >= 0x10100000L
++#if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
+     SSL_METHOD* meth = const_cast<SSL_METHOD*>(TLS_method());
+ #else
+     //
+diff --git a/cpp/src/IceSSL/OpenSSLTransceiverI.cpp b/cpp/src/IceSSL/OpenSSLTransceiverI.cpp
+index d66c5eb..9f07044 100644
+--- a/cpp/src/IceSSL/OpenSSLTransceiverI.cpp
++++ b/cpp/src/IceSSL/OpenSSLTransceiverI.cpp
+@@ -36,7 +36,7 @@ using namespace IceSSL;
+ //
+ // See: http://cvs.openssl.org/chngview?cn=22569
+ //
+-#if defined(OPENSSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x100000bfL
++#if defined(OPENSSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x100000bfL && !defined(LIBRESSL_VERSION_NUMBER)
+ namespace
+ {
+ 
+@@ -156,13 +156,13 @@ IceSSL::TransceiverI::initialize(IceInternal::Buffer& readBuffer, IceInternal::B
+         //
+         // See: http://cvs.openssl.org/chngview?cn=22569
+         //
+-#if defined(OPENSSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x100000bfL
++#if defined(OPENSSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x100000bfL && !defined(LIBRESSL_VERSION_NUMBER)
+         IceUtilInternal::MutexPtrLock<IceUtil::Mutex> sync(sslMutex);
+ #endif
+ 
+         int ret = _incoming ? SSL_accept(_ssl) : SSL_connect(_ssl);
+ 
+-#if defined(OPENSSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x100000bfL
++#if defined(OPENSSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x100000bfL && !defined(LIBRESSL_VERSION_NUMBER)
+         sync.release();
+ #endif
+         if(ret <= 0)
+diff --git a/cpp/src/IceSSL/Util.cpp b/cpp/src/IceSSL/Util.cpp
+index a60ee4c..50c47f3 100644
+--- a/cpp/src/IceSSL/Util.cpp
++++ b/cpp/src/IceSSL/Util.cpp
+@@ -110,7 +110,7 @@ namespace
+ {
+ 
+ #  ifndef OPENSSL_NO_DH
+-#    if OPENSSL_VERSION_NUMBER < 0x10100000L
++#    if OPENSSL_VERSION_NUMBER < 0x10100000L || defined(LIBRESSL_VERSION_NUMBER)
+ 
+ // The following arrays are predefined Diffie Hellman group parameters.
+ // These are known strong primes, distributed with the OpenSSL library
+@@ -228,7 +228,7 @@ unsigned char dh4096_g[] = { 0x02 };
+ //
+ // With OpenSSL 1.1.0 is no longer possible to acess the DH p and g
+ // data members to set the DH params. We still use the same default
+-// parameters but they were converted to DER format using 
++// parameters but they were converted to DER format using
+ // i2d_DHparams and can be restored using d2i_DHparams
+ 
+ unsigned char dh512[] =
+@@ -338,7 +338,7 @@ unsigned char dh4096[] =
+ //
+ // Convert a predefined parameter set into a DH value.
+ //
+-#    if OPENSSL_VERSION_NUMBER >= 0x10100000L
++#    if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
+ static DH*
+ convertDH(const unsigned char* buf, int len)
+ {
+@@ -428,7 +428,7 @@ IceSSL::DHParams::get(int keyLength)
+     // No match found. Use one of the predefined parameter sets instead.
+     //
+     IceUtil::Mutex::Lock sync(*this);
+-#    if OPENSSL_VERSION_NUMBER >= 0x10100000L
++#    if OPENSSL_VERSION_NUMBER >= 0x10100000L && !defined(LIBRESSL_VERSION_NUMBER)
+     if(keyLength >= 4096)
+     {
+         if(!_dh4096)
diff --git a/dev-libs/Ice/files/Ice-3.6.3-no-arch-opts.patch b/dev-libs/Ice/files/Ice-3.6.3-no-arch-opts.patch
new file mode 100644
index 0000000..149a31e
--- /dev/null
+++ b/dev-libs/Ice/files/Ice-3.6.3-no-arch-opts.patch
@@ -0,0 +1,50 @@
+--- ice-3.6.3/cpp/config/Make.rules.Linux~	2015-06-27 16:56:56.000000000 +0200
++++ ice-3.6.3/cpp/config/Make.rules.Linux	2015-06-27 17:23:45.810591931 +0200
+@@ -79,19 +79,6 @@
+         CXXARCHFLAGS	+= -mtune=v8 -pipe -Wno-deprecated -DICE_USE_MUTEX_SHARED
+     endif
+ 
+-    #
+-    # Only use multilib -m32/-m64 options for amd64 arch, x32 arch can also run
+-    # in amd64 macines but doesn't use multilib, in this case MACHINE_TYPE will
+-    # be x86_64 and HOST_ARCH x32.
+-    #
+-    ifeq ($(HOST_ARCH),amd64)
+-        ifeq ($(LP64),yes)
+-            CXXARCHFLAGS	+= -m64
+-        else
+-            CXXARCHFLAGS	+= -m32
+-        endif
+-    endif
+-
+     CXXFLAGS		+= $(CXXARCHFLAGS) -fvisibility=hidden -Wall -Werror -pthread
+ 
+     # If MAXWARN is set then enable extra warnings
+--- ice-3.6.3/config/Make.common.rules~	2015-06-23 17:30:20.000000000 +0200
++++ ice-3.6.3/config/Make.common.rules	2015-06-28 01:53:57.149666595 +0200
+@@ -101,25 +101,7 @@
+       ifeq ($(LP64),)
+           LP64      	= yes
+       endif
+-
+-      #
+-      # x86 binaries build on x86_64 machine use 32 binsuffix
+-      #
+-      ifneq ($(STATICLIBS),yes)
+-          ifneq ($(LP64),yes)
+-              binsuffix	= 32
+-          endif
+-      endif
+    endif
+-
+-   #
+-   # x86 builds uses 32 binsuffix
+-   #
+-   ifneq ($(STATICLIBS),yes)
+-	ifeq ($(findstring $(MACHINE_TYPE),i386 i486 i586 i686),$(MACHINE_TYPE))
+-	    binsuffix     = 32
+-	endif
+-    endif
+ endif
+ 
+ ifeq ($(CPP11),yes)