From 2ba055d7a33979e577e77b2e58682f3289c6c236 Mon Sep 17 00:00:00 2001
From: Gluzskiy Alexandr <sss@sss.chaoslab.ru>
Date: Sat, 13 Jan 2018 07:12:38 +0300
Subject: =?UTF-8?q?=09=D0=BD=D0=BE=D0=B2=D1=8B=D0=B9=20=D1=84=D0=B0=D0=B9?=
 =?UTF-8?q?=D0=BB:=20=20=20=20gst-plugins-libav-1.12.3-r1.ebuild?=
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

---
 .../gst-plugins-libav-1.12.3-r1.ebuild             | 78 ++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3-r1.ebuild

diff --git a/media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3-r1.ebuild b/media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3-r1.ebuild
new file mode 100644
index 0000000..b54a7a9
--- /dev/null
+++ b/media-plugins/gst-plugins-libav/gst-plugins-libav-1.12.3-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib-minimal
+
+MY_PN="gst-libav"
+DESCRIPTION="FFmpeg based gstreamer plugin"
+HOMEPAGE="https://gstreamer.freedesktop.org/modules/gst-libav.html"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="1.0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="libav +bundled-libav +orc"
+
+# XXX: bzip2/lzma are automagic
+# Move back to ${PV} deps of gstreamer/gst-plugins-base later; 1.10.4 had it reduced for lone security stabilization
+RDEPEND="
+	app-arch/bzip2
+	app-arch/xz-utils
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.12.0:1.0[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.12.0:1.0[${MULTILIB_USEDEP}]
+	!bundled-libav? (
+		!libav? ( >=media-video/ffmpeg-3.2.4:0=[${MULTILIB_USEDEP}] )
+	)
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+RESTRICT="test" # FIXME: tests seem to get stuck at one point; investigate properly
+
+multilib_src_configure() {
+	GST_PLUGINS_BUILD=""
+	# Upstream dropped support for system libav and won't work
+	# for preserving its compat anymore, forcing us to rely on internal
+	# ffmpeg copy if we don't want to cause unresolvable blockers for
+	# libav setups.
+	# https://bugzilla.gnome.org/show_bug.cgi?id=758183
+	# Prefer system ffmpeg for -libav
+	local myconf
+
+	if use libav; then
+		ewarn "Using internal ffmpeg copy as upstream dropped"
+		ewarn "the support for compiling against system libav"
+		ewarn "https://bugzilla.gnome.org/show_bug.cgi?id=758183"
+	elif use bundled-libav; then
+		ewarn "Using bundled ffmpeg"
+	else
+		myconf="--with-system-libav --enable-gpl"
+	fi
+
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-maintainer-mode \
+		--with-package-name="Gentoo GStreamer ebuild" \
+		--with-package-origin="https://www.gentoo.org" \
+		--disable-fatal-warnings \
+		$(use_enable orc) \
+		${myconf}
+}
+
+multilib_src_compile() {
+	# Don't build with -Werror
+	emake ERROR_CFLAGS=
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}
-- 
cgit v1.2.3