From f1e95daae05c57d935b00e611c624c5e75cd21ec Mon Sep 17 00:00:00 2001
From: "(no author)" <(no author)@4d9a9b59-111c-4e0b-8f7a-7640551abb98>
Date: Mon, 16 Mar 2009 07:55:01 +0000
Subject: uploading my overlay ), initial commit

git-svn-id: http://172.18.13.13/svn/sss_overlay@1 4d9a9b59-111c-4e0b-8f7a-7640551abb98
---
 dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild | 73 ++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild

(limited to 'dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild')

diff --git a/dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild b/dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild
new file mode 100644
index 0000000..b54d8c5
--- /dev/null
+++ b/dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/commoncpp2/commoncpp2-1.6.2.ebuild,v 1.1 2008/05/07 05:32:39 dev-zero Exp $
+
+inherit eutils autotools
+
+DESCRIPTION="GNU Common C++ is a C++ framework offering portable support for threading, sockets, file access, daemons, persistence, serial I/O, XML parsing, and system services"
+SRC_URI="mirror://gnu/commoncpp/${P}.tar.gz"
+HOMEPAGE="http://www.gnu.org/software/commoncpp/"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="debug doc examples ipv6 gnutls"
+
+RDEPEND="gnutls? ( dev-libs/libgcrypt
+		net-libs/gnutls )
+	!gnutls? ( dev-libs/openssl )
+	sys-libs/zlib"
+DEPEND="doc? ( >=app-doc/doxygen-1.3.6 )
+	${RDEPEND}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/1.6.1-gcc42_atomicity.patch" \
+		"${FILESDIR}/${PV}-autoconf.patch" \
+		"${FILESDIR}/${PV}-configure_detect_netfilter.patch"
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_compile() {
+	use doc || \
+		sed -i "s/^DOXYGEN=.*/DOXYGEN=no/" configure || die "sed failed"
+
+	local myconf
+	use gnutls || myconf="--with-openssl"
+
+	econf \
+		$(use_enable debug) \
+		$(use_with ipv6 ) \
+		${myconf} || die "econf failed"
+	emake -j1 || die "emake failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS NEWS ChangeLog README THANKS TODO COPYING.addendum
+
+	# Only install html docs
+	# man and latex available, but seems a little wasteful
+	use doc && dohtml doc/html/*
+
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		cd demo
+		doins *.cpp *.h *.xml README
+	fi
+}
+
+pkg_postinst() {
+	ewarn "There's a change in the ABI between version 1.5.x and 1.6.x, please"
+	ewarn "run the following command to find broken packages and rebuild them:"
+	ewarn "    revdep-rebuild --library=libccext2-1.5.so"
+}
+
+# Some of the tests hang forever
+#src_test() {
+#	cd "${S}/tests"
+#	emake || die "emake tests failed"
+#	./test.sh || die "tests failed"
+#}
-- 
cgit v1.2.3