# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit autotools eutils flag-o-matic multilib multilib-minimal subversion

DESCRIPTION="library for decoding DTS Coherent Acoustics streams used in DVD"
HOMEPAGE="http://www.videolan.org/developers/libdca.html"
SRC_URI=""

ESVN_REPO_URI="svn://svn.videolan.org/libdca/trunk"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="debug oss static-libs"

RDEPEND="!media-libs/libdts
	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r3
		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}"

DOCS=( AUTHORS ChangeLog NEWS README TODO doc/${PN}.txt )

src_prepare() {
	epatch "${FILESDIR}"/${P}-cflags.patch \
		"${FILESDIR}"/${P}-tests-optional.patch \

	eautoreconf
}

multilib_src_configure() {
	append-lfs-flags #328875

	ECONF_SOURCE="${S}" econf \
		--disable-dependency-tracking \
		$(use_enable debug) \
		$(use_enable static-libs static) \
		$(use_enable oss)

	# Those are thrown away afterwards, don't build them in the first place
	if [ "${ABI}" != "${DEFAULT_ABI}" ] ; then
		sed -i -e 's/ libao src//' Makefile || die
	fi
}

multilib_src_compile() {
	emake OPT_CFLAGS="" || die
}

multilib_src_install() {
	emake DESTDIR="${D}" install || die

	find "${ED}" -name '*.la' -exec rm -f '{}' +
	rm -f "${ED}"/usr/$(get_libdir)/libdts.a
}