git-svn-id: http://172.18.13.13/svn/sss_overlay@3 4d9a9b59-111c-4e0b-8f7a-7640551abb98

3 files changed, 263 insertions, 0 deletions

diff --git a/dev-libs/ptlib/ptlib-2.4.4.ebuild b/dev-libs/ptlib/ptlib-2.4.4.ebuild
new file mode 100644
index 0000000..b3b9f38
--- /dev/null
+++ b/dev-libs/ptlib/ptlib-2.4.4.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="1"
+
+inherit eutils
+
+DESCRIPTION="Network focused portable C++ class library providing high level functions"
+HOMEPAGE="http://www.opalvoip.org/"
+SRC_URI="mirror://sourceforge/opalvoip/${P}.tar.bz2"
+
+LICENSE="MPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa bsdvideo debug doc esd ieee1394 ipv6 ldap minimal noaudio novideo oss
+sasl sdl ssl sunaudio v4l v4l2 xml"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	esd? ( media-sound/esound )
+	ieee1394? ( media-libs/libdv
+		sys-libs/libavc1394
+		media-libs/libdc1394:1 )
+	ldap? ( net-nds/openldap )
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	sdl? ( media-libs/libsdl )
+	ssl? ( dev-libs/openssl )
+	xml? ( dev-libs/expat )"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	v4l? ( sys-kernel/linux-headers )
+	v4l2? ( sys-kernel/linux-headers )
+	!dev-libs/pwlib"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# this patch fixes bugs: #145424 and #140358
+	epatch "${FILESDIR}"/${PN}-asm.patch
+}
+
+src_compile() {
+	local myconf=""
+	local makeopts=""
+
+	use noaudio && myconf="${myconf} --disable-audio"
+	use novideo && myconf="${myconf} --disable-video"
+
+	econf \
+		${myconf} \
+		$(use_enable alsa) \
+		$(use_enable bsdvideo) \
+		$(use_enable debug exceptions) \
+		$(use_enable debug memcheck) \
+		$(use_enable esd) \
+		$(use_enable ieee1394 avc) \
+		$(use_enable ieee1394 dc) \
+		$(use_enable ipv6) \
+		$(use_enable ldap openldap) \
+		$(use_enable minimal minsize) \
+		$(use_enable oss) \
+		$(use_enable sasl) \
+		$(use_enable sdl) \
+		$(use_enable ssl openssl) \
+		$(use_enable sunaudio) \
+		$(use_enable v4l) \
+		$(use_enable v4l2) \
+		$(use_enable xml expat) \
+		--enable-plugins \
+		|| die "econf failed"
+
+	if use debug; then
+		makeopts="${makeopts} DEBUG=1 debug"
+	fi
+
+	emake ${makeopts} || die "emake failed"
+}
+
+src_install() {
+	local makeopts
+
+	makeopts="PREFIX=/usr DESTDIR=\"${D}\""
+
+	if use debug; then
+		makeopts="${makeopts} DEBUG=1"
+	fi
+
+	emake ${makeopts} install || die "emake install failed"
+
+	if use doc; then
+		dohtml -r html/* || die "documentation installation failed"
+	fi
+
+	dodoc ReadMe.txt ReadMe_QOS.txt History.txt || die "documentation
+ installation failed"
+}
diff --git a/net-im/ekiga/ekiga-3.0.2.ebuild b/net-im/ekiga/ekiga-3.0.2.ebuild
new file mode 100644
index 0000000..2f062bf
--- /dev/null
+++ b/net-im/ekiga/ekiga-3.0.2.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="1"
+
+inherit eutils gnome2
+
+DESCRIPTION="H.323 and SIP VoIP softphone"
+HOMEPAGE="http://www.ekiga.org/"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="avahi dbus debug doc eds gconf gnome ldap libnotify xv"
+
+RDEPEND=">=dev-libs/ptlib-2.4.2
+	>=net-libs/opal-3.4.2
+	>=x11-libs/gtk+-2.12.0:2
+	>=dev-libs/glib-2.8.0:2
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	avahi? ( >=net-dns/avahi-0.6.0 )
+	dbus? ( >=dev-libs/dbus-glib-0.36 )
+	eds? ( >=gnome-extra/evolution-data-server-1.2 )
+	gconf? ( >=gnome-base/gconf-2.6.0:2 )
+	gnome? ( >=gnome-base/libgnome-2.14.0
+		>=gnome-base/libgnomeui-2.14.0 )
+	ldap? ( net-nds/openldap )
+	libnotify? ( x11-libs/libnotify )
+	xv? ( x11-libs/libXv )"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	>=dev-util/pkgconfig-0.12.0
+	>=dev-util/intltool-0.35
+	doc? ( app-text/scrollkeeper
+		app-text/gnome-doc-utils )"
+
+DOCS="AUTHORS ChangeLog FAQ NEWS README"
+
+pkg_setup() {
+	# ekiga has to be built like opal and ptlib but as opal has to be built
+	# like ptlib, it should be possible to check only opal but as ekiga is
+	# linking to both, we are cheking both
+	if use debug && (! built_with_use dev-libs/ptlib debug ||
+		! built_with_use net-libs/opal debug); then
+		eerror "You need to build dev-libs/ptlib and net-libs/opal with\
+ USE=debug enabled."
+		die "dev-libs/ptlib and net-libs/opal have to be built with USE=debug"
+	fi
+
+	if ! use debug && (built_with_use dev-libs/ptlib debug ||
+		built_with_use net-libs/opal debug); then
+		eerror "You need to build dev-libs/ptlib and net-libs/opal without\
+ USE=debug."
+		die "dev-libs/ptlib and net-libs/opal has not to be built with USE=debug"
+	fi
+
+	# dbus-service is always enable if dbus is enable, no reason to disable it
+	G2CONF="${G2CONF}
+		$(use_enable avahi)
+		$(use_enable dbus)
+		$(use_enable dbus dbus_service)
+		$(use_enable debug)
+		$(use_enable doc gdu)
+		$(use_enable eds)
+		$(use_enable gconf)
+		$(use_enable gnome)
+		$(use_enable ldap)
+		$(use_enable libnotify notify)
+		$(use_enable xv)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# remove call to gconftool-2 --shutdown
+	sed -i -e '/gconftool-2 --shutdown/d' Makefile.in \
+		|| die "Patching Makefile.in failed"
+
+	# fix ekiga-helper dbus service .in file
+	sed -i -e 's/@PACKAGE_NAME@/ekiga/'\
+		src/components/org.ekiga.Helper.service.in \
+		|| die "Patching src/components/org.ekiga.Helper.service.in failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	if ! use gnome; then
+		ewarn "USE=-gnome is experimental, some weirdness with the UI and"
+		ewarn "config keys should appear."
+	fi
+}
diff --git a/net-libs/opal/opal-3.4.4.ebuild b/net-libs/opal/opal-3.4.4.ebuild
new file mode 100644
index 0000000..7231f62
--- /dev/null
+++ b/net-libs/opal/opal-3.4.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="C++ class library normalising numerous telephony protocols"
+HOMEPAGE="http://www.opalvoip.org/"
+SRC_URI="mirror://sourceforge/opalvoip/${P}.tar.bz2"
+
+LICENSE="MPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug doc java"
+
+RDEPEND=">=dev-libs/ptlib-2.0.0
+	>=media-video/ffmpeg-0.4.7
+	media-libs/speex
+	java? ( virtual/jdk )"
+
+pkg_setup() {
+	if use debug && ! built_with_use dev-libs/ptlib debug; then
+		eerror "You need to build dev-libs/ptlib with USE=debug enabled."
+		die "dev-libs/ptlib has to be built with USE=debug"
+	fi
+
+	if ! use debug && built_with_use dev-libs/ptlib debug; then
+		eerror "You need to build dev-libs/ptlib without USE=debug."
+		die "dev-libs/ptlib has not to be built with USE=debug"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-lpcini.patch
+}
+
+src_compile() {
+	local makeopts
+
+	filter-ldflags -Wl,--as-needed --as-needed
+
+	# zrtp doesn't depend on net-libs/libzrtpcpp but on libzrtp from
+	# http://zfoneproject.com/ that is not in portage
+	econf \
+		$(use_enable debug) \
+		$(use_enable java) \
+		--enable-plugins \
+		--disable-localspeex \
+		--disable-zrtp \
+		|| die "econf failed"
+
+	if use debug; then
+		makeopts="debug"
+	else
+		makeopts="opt"
+	fi
+
+	emake ${makeopts} || die "emake failed"
+}
+
+src_install() {
+	emake PREFIX=/usr DESTDIR="${D}" install || die "emake install failed"
+
+	if use doc; then
+		dohtml -r html/* docs/* || die "documentation installation failed"
+	fi
+}