added:

	cantata-scm
	picard-scm

2 files changed, 188 insertions, 0 deletions

diff --git a/media-sound/cantata/cantata-scm.ebuild b/media-sound/cantata/cantata-scm.ebuild
new file mode 100644
index 0000000..1f6d606
--- /dev/null
+++ b/media-sound/cantata/cantata-scm.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PLOCALES="cs de en_GB es fr hu ko pl ru zh_CN"
+inherit cmake-utils gnome2-utils l10n qmake-utils xdg git-r3
+
+DESCRIPTION="Featureful and configurable Qt client for the music player daemon (MPD)"
+HOMEPAGE="https://github.com/CDrummond/cantata"
+SRC_URI=""
+
+EGIT_REPO_URI="git://github.com/CDrummond/cantata"
+
+LICENSE="GPL-2"
+SLOT="4"
+KEYWORDS=""
+IUSE="cdda cddb http-server kde mtp musicbrainz qt5 replaygain taglib udisks"
+REQUIRED_USE="
+	cdda? ( udisks || ( cddb musicbrainz ) )
+	cddb? ( cdda taglib )
+	mtp? ( taglib udisks )
+	musicbrainz? ( cdda taglib )
+	qt5? ( !kde )
+	replaygain? ( taglib )
+"
+
+RDEPEND="
+	dev-db/sqlite:3
+	sys-libs/zlib
+	x11-libs/libX11
+	|| ( kde-frameworks/breeze-icons:5 kde-frameworks/oxygen-icons:* )
+	cdda? ( media-sound/cdparanoia )
+	cddb? ( media-libs/libcddb )
+	kde? ( kde-base/kdelibs:4 )
+	mtp? ( media-libs/libmtp )
+	musicbrainz? ( media-libs/musicbrainz:5 )
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	!qt5? (
+		dev-libs/qjson
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		dev-qt/qtsql:4
+		dev-qt/qtsvg:4
+	)
+	replaygain? (
+		media-libs/libebur128
+		media-sound/mpg123
+		virtual/ffmpeg
+	)
+	taglib? (
+		media-libs/taglib[asf,mp4]
+		media-libs/taglib-extras
+		!kde? ( udisks? ( sys-fs/udisks:2 ) )
+	)
+"
+DEPEND="${RDEPEND}
+	kde? ( sys-devel/gettext )
+	!kde? ( qt5? ( dev-qt/linguist-tools:5 ) )
+"
+
+# cantata has no tests
+RESTRICT="test"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	l10n_find_plocales_changes 'po' '' '.po'
+}
+
+src_configure() {
+	local langs="$(l10n_get_locales)"
+
+	local mycmakeargs=(
+		-DCANTATA_TRANSLATIONS="${langs// /;}"
+		-DENABLE_CDPARANOIA=$(usex cdda)
+		-DENABLE_CDDB=$(usex cddb)
+		-DENABLE_HTTP_SERVER=$(usex http-server)
+		-DENABLE_KDE=$(usex kde)
+		-DENABLE_MTP=$(usex mtp)
+		-DENABLE_MUSICBRAINZ=$(usex musicbrainz)
+		-DENABLE_QT5=$(usex qt5)
+		-DENABLE_FFMPEG=$(usex replaygain)
+		-DENABLE_MPG123=$(usex replaygain)
+		-DENABLE_TAGLIB=$(usex taglib)
+		-DENABLE_TAGLIB_EXTRAS=$(usex taglib)
+		-DENABLE_DEVICES_SUPPORT=$(usex udisks)
+		-DENABLE_HTTP_STREAM_PLAYBACK=OFF
+		-DENABLE_REMOTE_DEVICES=OFF
+		-DENABLE_UDISKS2=ON
+		-DUSE_SYSTEM_MENU_ICON=OFF
+	)
+
+	if ! use kde; then
+		if use qt5; then
+			mycmakeargs+=(
+				-DLCONVERT_EXECUTABLE="$(qt5_get_bindir)/lconvert"
+				-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
+			)
+		else
+			mycmakeargs+=(
+				-DLCONVERT_EXECUTABLE="$(qt4_get_bindir)/lconvert"
+				-DLRELEASE_EXECUTABLE="$(qt4_get_bindir)/lrelease"
+			)
+		fi
+	fi
+
+	cmake-utils_src_configure
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_pkg_postrm
+}
diff --git a/media-sound/picard/picard-scm.ebuild b/media-sound/picard/picard-scm.ebuild
new file mode 100644
index 0000000..37a6331
--- /dev/null
+++ b/media-sound/picard/picard-scm.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+DISABLE_AUTOFORMATTING=true
+inherit eutils distutils-r1 readme.gentoo git-r3
+
+DESCRIPTION="A cross-platform music tagger"
+HOMEPAGE="http://picard.musicbrainz.org/"
+SRC_URI=""
+
+EGIT_REPO_URI="git://github.com/metabrainz/picard"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+acoustid +cdda nls"
+
+DEPEND="dev-python/PyQt4[X,${PYTHON_USEDEP}]
+	dev-qt/qtgui:4[accessibility]
+	media-libs/mutagen
+	acoustid? ( >=media-libs/chromaprint-1.0[tools] )
+	cdda? ( dev-python/python-discid )"
+RDEPEND="${DEPEND}"
+
+RESTRICT="test" # doesn't work with ebuilds
+#S=${WORKDIR}/${PN}-release-${PV}
+DOCS="AUTHORS.txt NEWS.txt"
+
+DOC_CONTENTS="If you are upgrading Picard and it does not start,
+try removing Picard's settings:
+    rm ~/.config/MusicBrainz/Picard.conf
+
+You should set the environment variable BROWSER to something like
+    firefox '%s' &
+to let python know which browser to use."
+
+src_compile() {
+	distutils-r1_src_compile $(use nls || echo "--disable-locales")
+}
+
+src_install() {
+	distutils-r1_src_install --disable-autoupdate --skip-build \
+		$(use nls || echo "--disable-locales")
+
+	doicon picard.ico
+	domenu picard.desktop
+	readme.gentoo_create_doc
+}