easytag-scm

2 files changed, 110 insertions, 0 deletions

diff --git a/media-sound/easytag/easytag-scm.ebuild b/media-sound/easytag/easytag-scm.ebuild
new file mode 100644
index 0000000..ced0632
--- /dev/null
+++ b/media-sound/easytag/easytag-scm.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit fdo-mime gnome2-utils git-r3
+
+DESCRIPTION="GTK+ utility for editing MP2, MP3, MP4, FLAC, Ogg and other media tags"
+HOMEPAGE="https://wiki.gnome.org/Apps/EasyTAG"
+SRC_URI=""
+
+EGIT_REPO_URI="git://git.gnome.org/easytag"
+
+LICENSE="GPL-2 GPL-2+ LGPL-2 LGPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS=""
+IUSE="flac mp3 mp4 opus speex test vorbis wavpack"
+REQUIRED_USE="opus? ( vorbis )
+	speex? ( vorbis )"
+
+RDEPEND=">=dev-libs/glib-2.38:2
+	media-libs/libcanberra[gtk3]
+	>=x11-libs/gtk+-3.10:3
+	dev-util/appdata-tools
+	flac? ( >=media-libs/flac-1.3 )
+	mp3? (
+		>=media-libs/id3lib-3.8.3-r8
+		>=media-libs/libid3tag-0.15.1b-r4
+		)
+	mp4? ( >=media-libs/taglib-1.9.1[mp4] )
+	opus? (
+		>=media-libs/opus-1.1
+		>=media-libs/opusfile-0.4
+		)
+	speex? ( >=media-libs/speex-1.2_rc1 )
+	vorbis? (
+		>=media-libs/libogg-1.3.1
+		>=media-libs/libvorbis-1.3.4
+		)
+	wavpack? ( >=media-sound/wavpack-4.70 )"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.4
+	app-text/yelp-tools
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-util/intltool-0.50
+	>=sys-devel/gettext-0.18.3.2
+	virtual/pkgconfig
+	!<dev-util/pkgconfig-0.27
+	test? (
+		dev-libs/appstream-glib
+		>=dev-util/desktop-file-utils-0.22
+		)"
+
+DOCS=( AUTHORS ChangeLog HACKING NEWS README THANKS TODO )
+
+src_prepare() {
+	./autogen.sh
+	default
+
+	sed -i \
+		-e '/^DEPRECATED_CPPFLAGS="/d' \
+		-e '/warning_flags/s: -Werror=.*:":' \
+		configure || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable test appdata-validate) \
+		$(use_enable test tests) \
+		$(use_enable mp3) \
+		$(use_enable mp3 id3v23) \
+		$(use_enable vorbis ogg) \
+		$(use_enable opus) \
+		$(use_enable speex) \
+		$(use_enable flac) \
+		$(use_enable mp4) \
+		$(use_enable wavpack)
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+	gnome2_schemas_update
+}
diff --git a/media-sound/easytag/metadata.xml b/media-sound/easytag/metadata.xml
new file mode 100644
index 0000000..029def4
--- /dev/null
+++ b/media-sound/easytag/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>sound@gentoo.org</email>
+		<name>Gentoo Sound project</name>
+	</maintainer>
+	<use>
+		<flag name="opus">Enable support for <pkg>media-libs/opus</pkg> and <pkg>media-libs/opusfile</pkg> (opus audio codec)</flag>
+		<flag name="gtk2">Enable GTK+:2 support and disable default GTK+:3 support</flag>
+		<flag name="gtk3">Enable GTK+:3 support (default) and disable GTK+:2 support</flag>
+	</use>
+	<longdescription>a utility for viewing and editing tags for MP3, MP2, FLAC, AAC, MP4 and OGG files. It features a simple and attractive GTK+ interface</longdescription>
+</pkgmetadata>