addded ncrack and thc-hydra scm builds

3 files changed, 145 insertions, 0 deletions

diff --git a/net-analyzer/hydra/hydra-scm.ebuild b/net-analyzer/hydra/hydra-scm.ebuild
new file mode 100644
index 0000000..f82a52a
--- /dev/null
+++ b/net-analyzer/hydra/hydra-scm.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils toolchain-funcs git-r3
+
+DESCRIPTION="Advanced parallized login hacker"
+HOMEPAGE="http://www.thc.org/thc-hydra/"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/vanhauser-thc/thc-hydra"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE="firebird gtk idn mysql ncp oracle pcre postgres ssl subversion"
+
+RDEPEND="
+	dev-libs/openssl
+	sys-libs/ncurses
+	firebird? ( dev-db/firebird )
+	gtk? (
+		dev-libs/atk
+		dev-libs/glib:2
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:2
+	)
+	idn? ( net-dns/libidn )
+	mysql? ( virtual/mysql )
+	ncp? ( net-fs/ncpfs )
+	oracle? ( dev-db/oracle-instantclient-basic )
+	pcre? ( dev-libs/libpcre )
+	postgres? ( dev-db/postgresql )
+	ssl? ( >=net-libs/libssh-0.4.0 )
+	subversion? ( dev-vcs/subversion )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# None of the settings in Makefile.unix are useful to us
+	: > Makefile.unix
+
+	sed -i \
+		-e 's:|| echo.*$::' \
+		-e '/\t-$(CC)/s:-::' \
+		-e '/^OPTS/{s|=|+=|;s| -O3||}' \
+		-e '/ -o /s:$(OPTS):& $(LDFLAGS):g' \
+		Makefile.am || die
+
+}
+
+src_configure() {
+	export OPTS="${CFLAGS}"
+
+	if ! use subversion; then
+		sed -i 's/-lsvn_client-1 -lapr-1 -laprutil-1 -lsvn_subr-1//;s/-DLIBSVN//' configure || die
+	fi
+
+	if ! use mysql; then
+		sed -i 's/-lmysqlclient//;s/-DLIBMYSQLCLIENT//' configure || die
+	fi
+
+	# Linking against libtinfo might be enough here but pkg-config --libs tinfo
+	# would require a USE=tinfo flag and recent linkers should drop libcurses
+	# as needed
+	sed -i \
+		-e 's|-lcurses|'"$( $(tc-getPKG_CONFIG) --libs ncurses)"'|g' \
+		configure || die
+
+	# Note: despite the naming convention, the top level script is not an
+	# autoconf-based script.
+	export NCP_PATH=$(usex ncp /usr/$(get_libdir) '')
+	export NCP_IPATH=$(usex ncp /usr/include '')
+	sh configure \
+		--prefix=/usr \
+		--nostrip \
+		$(use gtk && echo --disable-xhydra) \
+			|| die
+
+	if use gtk ; then
+		cd hydra-gtk && \
+		econf
+	fi
+}
+
+src_compile() {
+	tc-export CC
+	emake XLIBPATHS=''
+	use gtk && emake -C hydra-gtk
+}
+
+src_install() {
+	dobin hydra pw-inspector
+	use gtk && dobin hydra-gtk/src/xhydra
+	dodoc CHANGES README
+}
diff --git a/net-analyzer/hydra/metadata.xml b/net-analyzer/hydra/metadata.xml
new file mode 100644
index 0000000..40f7b4b
--- /dev/null
+++ b/net-analyzer/hydra/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+<email>netmon@gentoo.org</email>
+<name>Gentoo network monitoring and analysis project</name>
+</maintainer>
+<longdescription>Advanced parallized login hacker</longdescription>
+<use><flag name="ncp">NCP protocol (NetWare) support through <pkg>net-fs/ncpfs</pkg></flag></use>
+</pkgmetadata>
diff --git a/net-analyzer/ncrack/ncrack-scm.ebuild b/net-analyzer/ncrack/ncrack-scm.ebuild
new file mode 100644
index 0000000..460b35c
--- /dev/null
+++ b/net-analyzer/ncrack/ncrack-scm.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit base versionator git-r3
+
+EGIT_REPO_URI="https://github.com/nmap/ncrack"
+
+
+DESCRIPTION="a high-speed network authentication cracking tool"
+HOMEPAGE="http://nmap.org/ncrack/"
+SRC_URI=""
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="ssh ssl"
+
+RDEPEND="ssl? ( dev-libs/openssl )
+	ssh? ( net-misc/openssh )"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGELOG docs/{AUTHORS,TODO,{devguide,mirror_pool,ncrack\.usage,openssh-library}.txt} )
+
+
+src_configure() {
+	econf --with-openssl=$(use ssl && echo yes || echo no) \
+		--with-openssh=$(use ssh && echo yes || echo no)
+}
+
+src_install() {
+	base_src_install
+	doman docs/${PN}.1 || die "doman failed"
+}