2 files changed, 106 insertions, 0 deletions
diff --git a/net-p2p/pybitmessage/metadata.xml b/net-p2p/pybitmessage/metadata.xml
new file mode 100644
index 0000000..72a9c81
--- /dev/null
+++ b/net-p2p/pybitmessage/metadata.xml
@@ -0,0 +1,29 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <!-- maintainer-needed -->
+  <longdescription lang="en">
+    Bitmessage is a P2P communications protocol used to send encrypted
+    messages to another person or to many subscribers. It is
+    decentralized and trustless, meaning that you need-not inherently
+    trust any entities like root certificate authorities. It uses
+    strong authentication which means that the sender of a message
+    cannot be spoofed, and it aims to hide "non-content" data, like
+    the sender and receiver of messages, from passive eavesdroppers
+    like those running warrantless wiretapping programs.
+  </longdescription>
+  <upstream>
+    <bugs-to>
+      https://github.com/Bitmessage/PyBitmessage/issues
+    </bugs-to>
+    <doc lang="en">
+      https://bitmessage.org/wiki/PyBitmessage_Help
+    </doc>
+    <remote-id type="github">Bitmessage/PyBitmessage</remote-id>
+  </upstream>
+  <use>
+    <flag name="opencl">
+      Uses <pkg>dev-python/pyopencl</pkg> for GPU acceleration.
+    </flag>
+  </use>
+</pkgmetadata>
diff --git a/net-p2p/pybitmessage/pybitmessage-scm.ebuild b/net-p2p/pybitmessage/pybitmessage-scm.ebuild
new file mode 100644
index 0000000..ac7895b
--- /dev/null
+++ b/net-p2p/pybitmessage/pybitmessage-scm.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+# See https://github.com/Bitmessage/PyBitmessage/pull/952 for
+# why ipv6 is needed at the moment.
+PYTHON_REQ_USE="ipv6,sqlite"
+
+inherit distutils-r1 gnome2-utils git-r3
+
+MY_PN="PyBitmessage"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="P2P communications protocol"
+HOMEPAGE="https://bitmessage.org/"
+SRC_URI=""
+EGIT_REPO_URI="https://github.com/Bitmessage/PyBitmessage.git"
+EGIT_BRANCH="v0.6"
+LICENSE="MIT"
+SLOT="0/0.6"
+KEYWORDS=""
+IUSE="libressl ncurses opencl qt4 sound"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+
+# Some of these can be determined from src/depends.py.
+# The sound deps were found in src/bitmessageqt/__init__.py.
+# And src/openclpow.py imports numpy directly, so throw that in too.
+#
+# All of the dependencies that are behind USE flags are detected
+# and enabled automagically, so maybe it would be better if we
+# required them unconditionally?
+RDEPEND="${DEPEND}
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	!libressl? ( dev-libs/openssl:0[-bindist] )
+	libressl? ( dev-libs/libressl )
+	ncurses? ( dev-python/pythondialog[${PYTHON_USEDEP}] )
+	opencl? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pyopencl[${PYTHON_USEDEP}]
+	)
+	qt4? ( dev-python/PyQt4[${PYTHON_USEDEP}] )
+	sound? ( || (
+		media-sound/gst123
+		media-sound/alsa-utils
+		media-sound/mpg123
+	) )"
+
+
+src_install () {
+	distutils-r1_src_install
+	dodoc README.md
+
+	# The man page is not installed because it's basically empty.
+
+	if use qt4 ; then
+		newicon -s 24 desktop/icon24.png "${PN}.png"
+		newicon -s scalable desktop/can-icon.svg "${PN}.svg"
+		domenu "desktop/${PN}.desktop"
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}