blob: 01c60011ae35f9004f4fbe7da2d383b392c1931b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-3.2.2.ebuild,v 1.1 2014/10/14 23:34:31 pesa Exp $
EAPI=5
PLOCALES="cs de fr ja pl ru sl zh_CN zh_TW"
inherit eutils l10n multilib qmake-utils git-r3
DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
HOMEPAGE="http://qt-project.org/wiki/Category:Tools::QtCreator"
LICENSE="|| ( LGPL-2.1 LGPL-3 )"
EGIT_REPO_URI=(
"git://gitorious.org/${PN}/${PN}.git"
"https://git.gitorious.org/${PN}/${PN}.git"
)
SLOT="0"
KEYWORDS=""
# TODO: qbs:qbsprojectmanager, winrt (both require qt5)
QTC_PLUGINS=(android autotools:autotoolsprojectmanager baremetal bazaar
clang:clangcodemodel clearcase cmake:cmakeprojectmanager cvs git
ios mercurial perforce python:pythoneditor qnx subversion valgrind)
IUSE="debug doc examples test ${QTC_PLUGINS[@]%:*}"
# minimum Qt version required
QT_PV="5"
CDEPEND="
=dev-libs/botan-1.10*[threads]
dev-qt/designer:${QT_PV}
dev-qt/qtcore:${QT_PV}
dev-qt/qtdeclarative:${QT_PV}
dev-qt/qtgui:${QT_PV}
dev-qt/qthelp:${QT_PV}
dev-qt/qdoc:${QT_PV}
dev-qt/qtscript:${QT_PV}
dev-qt/qtsql:${QT_PV}
dev-qt/qtsvg:${QT_PV}
clang? ( >=sys-devel/clang-3.2:= )
"
DEPEND="${CDEPEND}
virtual/pkgconfig
test? ( dev-qt/qttest:${QT_PV} )
"
RDEPEND="${CDEPEND}
>=sys-devel/gdb-7.2[client(+),python]
examples? ( dev-qt/qtdemo:${QT_PV} )
"
PDEPEND="
autotools? ( sys-devel/autoconf )
bazaar? ( dev-vcs/bzr )
cmake? ( dev-util/cmake )
cvs? ( dev-vcs/cvs )
git? ( dev-vcs/git )
mercurial? ( dev-vcs/mercurial )
subversion? ( dev-vcs/subversion )
valgrind? ( dev-util/valgrind )
"
src_prepare() {
# disable unwanted plugins
for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
if ! use ${plugin%:*}; then
einfo "Disabling ${plugin%:*} plugin"
sed -i -re "/(^\s+|SUBDIRS\s*\+=\s*)${plugin#*:}\>/d" \
src/plugins/plugins.pro \
|| die "failed to disable ${plugin%:*} plugin"
fi
done
# fix translations
sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
share/qtcreator/translations/translations.pro || die
# remove bundled qbs
rm -rf src/shared/qbs || die
}
src_configure() {
EQMAKE5_EXCLUDE="share/qtcreator/templates/*
tests/*"
eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
IDE_PACKAGE_MODE=1 \
LLVM_INSTALL_DIR="${EPREFIX}/usr" \
TEST=$(use test && echo 1 || echo 0) \
USE_SYSTEM_BOTAN=1
}
src_test() {
echo ">>> Test phase [QTest]: ${CATEGORY}/${PF}"
cd tests/auto || die
EQMAKE5_EXCLUDE="valgrind/*"
eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)"
default
}
src_install() {
emake INSTALL_ROOT="${ED}usr" install
dodoc dist/{changes-*,known-issues}
# install documentation
if use doc; then
emake docs
insinto /usr/share/doc/${PF}
doins share/doc/qtcreator/qtcreator{,-dev}.qch
docompress -x /usr/share/doc/${PF}/qtcreator{,-dev}.qch
fi
# install desktop file
make_desktop_entry qtcreator 'Qt Creator' QtProject-qtcreator 'Qt;Development;IDE'
}
|
