blob: b54a7a970b7e9931f29bed561e57066475902869 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils multilib-minimal
MY_PN="gst-libav"
DESCRIPTION="FFmpeg based gstreamer plugin"
HOMEPAGE="https://gstreamer.freedesktop.org/modules/gst-libav.html"
SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
LICENSE="GPL-2"
SLOT="1.0"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 x86 ~amd64-fbsd ~x86-fbsd"
IUSE="libav +bundled-libav +orc"
# XXX: bzip2/lzma are automagic
# Move back to ${PV} deps of gstreamer/gst-plugins-base later; 1.10.4 had it reduced for lone security stabilization
RDEPEND="
app-arch/bzip2
app-arch/xz-utils
>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
>=media-libs/gstreamer-1.12.0:1.0[${MULTILIB_USEDEP}]
>=media-libs/gst-plugins-base-1.12.0:1.0[${MULTILIB_USEDEP}]
!bundled-libav? (
!libav? ( >=media-video/ffmpeg-3.2.4:0=[${MULTILIB_USEDEP}] )
)
orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}
>=dev-util/gtk-doc-am-1.12
>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
"
S="${WORKDIR}/${MY_PN}-${PV}"
RESTRICT="test" # FIXME: tests seem to get stuck at one point; investigate properly
multilib_src_configure() {
GST_PLUGINS_BUILD=""
# Upstream dropped support for system libav and won't work
# for preserving its compat anymore, forcing us to rely on internal
# ffmpeg copy if we don't want to cause unresolvable blockers for
# libav setups.
# https://bugzilla.gnome.org/show_bug.cgi?id=758183
# Prefer system ffmpeg for -libav
local myconf
if use libav; then
ewarn "Using internal ffmpeg copy as upstream dropped"
ewarn "the support for compiling against system libav"
ewarn "https://bugzilla.gnome.org/show_bug.cgi?id=758183"
elif use bundled-libav; then
ewarn "Using bundled ffmpeg"
else
myconf="--with-system-libav --enable-gpl"
fi
ECONF_SOURCE=${S} \
econf \
--disable-maintainer-mode \
--with-package-name="Gentoo GStreamer ebuild" \
--with-package-origin="https://www.gentoo.org" \
--disable-fatal-warnings \
$(use_enable orc) \
${myconf}
}
multilib_src_compile() {
# Don't build with -Werror
emake ERROR_CFLAGS=
}
multilib_src_install_all() {
einstalldocs
prune_libtool_files --modules
}
|
