blob: 8fedd4dbfb2e929e9760fe4d395a586bec1e712b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI="6"
inherit eutils flag-o-matic readme.gentoo-r1 systemd toolchain-funcs versionator user git-r3
EGIT_REPO_URI="https://git.torproject.org/tor.git"
DESCRIPTION="Anonymizing overlay network for TCP"
HOMEPAGE="http://www.torproject.org/"
SRC_URI=""
LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="libressl lzma scrypt seccomp selinux systemd tor-hardening test web zstd"
DEPEND="
app-text/asciidoc
dev-libs/libevent[ssl]
sys-libs/zlib
!libressl? ( dev-libs/openssl:0=[-bindist] )
libressl? ( dev-libs/libressl:0= )
lzma? ( app-arch/xz-utils )
scrypt? ( app-crypt/libscrypt )
seccomp? ( sys-libs/libseccomp )
systemd? ( sys-apps/systemd )
zstd? ( app-arch/zstd )"
RDEPEND="${DEPEND}
selinux? ( sec-policy/selinux-tor )"
DOCS=( README ChangeLog ReleaseNotes doc/HACKING )
pkg_setup() {
enewgroup tor
enewuser tor -1 -1 /var/lib/tor tor
}
src_prepare() {
./autogen.sh
default
}
src_configure() {
# Upstream isn't sure of all the user provided CFLAGS that
# will break tor, but does recommend against -fstrict-aliasing.
# We'll filter-flags them here as we encounter them.
filter-flags -fstrict-aliasing
econf \
--localstatedir="${EPREFIX}/var" \
--enable-system-torrc \
--enable-asciidoc \
--disable-libfuzzer \
--disable-rust \
$(use_enable scrypt libscrypt) \
$(use_enable seccomp) \
$(use_enable systemd) \
$(use_enable tor-hardening gcc-hardening) \
$(use_enable tor-hardening linker-hardening) \
$(use_enable web tor2web-mode) \
$(use_enable test unittests) \
$(use_enable test coverage)
}
src_install() {
default
readme.gentoo_create_doc
newconfd "${FILESDIR}"/tor.confd tor
newinitd "${FILESDIR}"/tor.initd-r8 tor
systemd_dounit contrib/dist/tor.service
keepdir /var/lib/tor
fperms 750 /var/lib/tor
fowners tor:tor /var/lib/tor
insinto /etc/tor/
newins "${FILESDIR}"/torrc-r1 torrc
}
|
